Amiga Games: Greatest Hits 1996/Amiga Games: Greatest Hits 1996.iso/archive/userbox/publicdomain/afilofaxpro23.lha/AFiloFaxPro23/Installer-Skript

Text File | 1996-06-08 | 5KB | 170 lines

(set lib "libs/reqtools.library")
(set tf "gadgets/textfield.gadget")

(if (= "deutsch" @language)
(
    (set #welcome "\nDieses Skript installiert AFiloFaxPro und alle dazugehörigen Dateien auf Ihrer Festplatte. \n\nAFiloFaxPro © 1995-96 by Frank Weber.")
    (set #destprompt "Bitte Zielverzeichnis wählen.\n(Ein Verzeichnis 'AFiloFaxPro' wird dort erstellt.)")
    (set #desthelp "Sie müssen hier das Verzeichnis wählen,\nin dem die 'AFiloFaxPro'-Schublade erstellt werden soll.\n\n In diese Schublade werden dann|AFiloFaxPro und alle dazugehörigen Dateien\nkopiert.")
    (set #overwritemsg "\nAFiloFaxPro wurde bereits in dieses Verzeichnis installiert.\n\nAltes AFiloFaxPro-Verzeichnis löschen ???")
    (set #overwritehelp "\nIn dem Verzeichnis, das Sie ausgewählt haben, existiert bereits ein Verzeichnis mit dem Namen 'AFiloFaxPro'.\n\nAntworten Sie 'Ja', wenn Sie das alte Verzeichnis komplett löschen möchten, bevor diese Version installiert wird.")
    (set #copyafc "Wohin soll das Hintergrundprogramm AFiloCron kopiert werden?")
    (set #copyafchelp "AFiloCron ist das Hintergrundprogramm, das ständig über evtl. auftretende Termine wacht und auch die Statistikdateien erstellt.\n\nEs sollte immer aktiv sein, darum sollten Sie es im WBStartup-Verzeichnis installieren.")
    (set #copyreqtools "\nReqtools.library kopieren...")
    (set #copytf "\ntextfield.gadget kopieren...")
)
(
    (set #welcome "\nThis script will install AFiloFaxPro and all supported files onto your Harddisk.\n\nAFiloFaxPro © 1995-96 by Frank Weber.")
    (set #destprompt "Please choose destination path.\n(A drawer called 'AFiloFaxPro' will be created there.)")
    (set #desthelp "Here you have to choose where the\n'AFiloFaxPro' drawer should be created.\n\nAFiloFaxPro and all supported files will\nbe copied into the 'AFiloFaxPro' directory.")
    (set #overwritemsg "\nAFiloFaxPro has already been installed into this directory.\n\nDelete old directory ???")
    (set #overwritehelp "\nThere is already a directory called 'AFiloFaxPro' in the directory chosen by you.\n\nSelect yes if you want the whole directory to be deleted before this version is installed.")
    (set #copyafc "Where is the AFiloCron to be installed?")
    (set #copyafchelp "AFiloCron is the background task waiting for events to occur.\n\nIs it should always be running, so you should place it in your 'WBStartup' drawer.")
    (set #copyreqtools "\nInstalling reqtools.library")
    (set #copytf "\nInstalling textfield.gadget")
))
(set @nohelp " ")

(message #welcome)

(set default-dir "SYS:")
(set @default-dest "SYS:")

(set @dest (askdir (prompt #destprompt)
                   (help #desthelp)
                   (default @default-dest)
           )
)

(set @affdrawer (tackon @dest "AFiloFaxPro"))
(set @default-dest @dest)

(if (exists @affdrawer)
(
  (if (> @user-level 1)
  (
    (set overwrite (askbool
                           (prompt #overwritemsg)
                           (help #overwritehelp)
                           (default 0)
                   )
    )
    (if (= 1 overwrite)
      (run (cat "c:delete QUIET ALL " @affdrawer))
    )
  ))
))

(makedir @affdrawer(infos))

(copyfiles  (source "AFiloFax")
            (dest @affdrawer)
            (infos)
)

(copyfiles  (source "Anleitung.guide")
            (dest @affdrawer)
            (infos)
)


(copyfiles  (source "Readme")
            (dest @affdrawer)
            (infos)
)

(copyfiles  (source "Liesmich")
            (dest @affdrawer)
            (infos)
)

(copyfiles  (source "RegiTool")
            (dest @affdrawer)
            (infos)
)

(makedir (tackon @affdrawer "pics"))

(copyfiles (source "pics/")
           (dest (tackon @affdrawer "pics"))
           (pattern "#?")
)

(set @afcdest (askdir (prompt #copyafc)
                     (help #copyafchelp)
                     (default "SYS:WBStartup")
             )
)

(copyfiles  (source "AFiloCron")
            (dest @afcdest)
            (infos)
)


(copylib    (prompt #copyreqtools)
            (help @nohelp)
            (source lib)
            (dest "LIBS:")
            (confirm)
)

(copylib    (prompt #copytf)
            (help @nohelp)
            (source tf)
            (dest "LIBS:gadgets")
            (confirm)
)

(tooltype (dest (tackon @affdrawer "AFiloFax"))
          (settooltype "REGITOOL" (tackon @affdrawer "RegiTool"))
)

(tooltype (dest (tackon @afcdest "AFiloCron"))
          (settooltype "REGITOOL" (tackon @affdrawer "RegiTool"))
)

(tooltype (dest (tackon @affdrawer "AFiloFax"))
          (settooltype "DOC" (tackon @affdrawer "Anleitung.guide"))
)

(tooltype (dest (tackon @afcdest "AFiloCron"))
          (settooltype "DOC" (tackon @affdrawer "Anleitung.guide"))
)

(tooltype (dest (tackon @afcdest "AFiloCron"))
          (settooltype "AFILOFAX" (tackon @affdrawer "AFiloFax"))
)

(if (< (/ (getversion) 65536) 38)
    (tooltype (dest (tackon @affdrawer "Anleitung.guide"))
              (setdefaulttool "sys:utilities/AmigaGuide")
    )

    (tooltype (dest (tackon @affdrawer "Anleitung.guide"))
              (setdefaulttool "sys:utilities/Multiview")
    )

)

(if (not (exists "s:aff_data"))
  (makedir "s:aff_data")
)

(if (exists "AFF.key")
    (copyfiles (source "AFF.key")
               (dest "S:")
    )

    (tooltype (dest (tackon @affdrawer "AFiloFax"))
              (settooltype "KEYFILE" "S:AFF.key")
    )
    (tooltype (dest (tackon @afcdest "AFiloCron"))
              (settooltype "KEYFILE" "S:AFF.key")
    )


)